2連 ディスプレイ 搭載可能な ESP32 の FRISK ケース作ってみた

スケッチの入力

今回は FRISK ケースを作ることが目的だったので、スケッチはザッと作った感じです。
いろいろ穴だらけだと思いますので、動作は保証しません。
ただ、不具合等があったらコメント投稿等でご連絡いただけると助かります。
解説も省略させていただきます。
いろいろ無駄が多いと思いますが、ご容赦ください。

因みに、ご自分の地域の天気予報に変えたい場合は以下のリンクから、URL を探し当てて修正してください。

https://weather.yahoo.co.jp/weather/rss/

【ソースコード】 (※無保証　※PCの場合、ダブルクリックすればコード全体を選択できます)

#include <WiFi.h>
#include "TimeLib.h" //Arduino time library ver1.5
#include "ESP32_SPIFFS_SSD1331_Gadgets.h" //beta ver 1.1
#include "ESP32_SPIFFS_ShinonomeFNT.h" //beta ver 1.32
#include "ESP32_SPIFFS_UTF8toSJIS.h" //beta ver 1.2
#include "ESP32_SSD1331.h" //beta ver 1.71
#include "ESP32_I2C_SSD1306.h" //mgo-tec library beta ver 1.20
#include "ESP32_WebGet.h" //beta ver 1.13

const char* ssid = "xxxxxxxx"; //ご自分のルーターのSSIDに書き換えてください
const char* password = "xxxxxxxx"; //ご自分のルーターのパスワードに書き換えてください
  
const char* UTF8SJIS_file = "/font/Utf8Sjis.tbl"; //UTF8 Shift_JIS 変換テーブルファイル名を記載しておく
const char* Shino_Zen_Font_file = "/font/shnmk16.bdf"; //全角フォントファイル名を定義
const char* Shino_Half_Font_file = "/font/shnm8x16.bdf"; //半角フォントファイル名を定義
const char* MyFont_file = "/font/MyFont.fnt"; //自作フォントファイル名を定義

const uint8_t SCLK_OLED =  14; //SCLK
const uint8_t MOSI_OLED =  13; //MOSI (Master Output Slave Input)
const uint8_t MISO_OLED =  12; //これは実際は使っていない。MISO (Master Input Slave Output)
const uint8_t CS_OLED = 15;
const uint8_t DC_OLED =  21; //OLED DC(Data/Command)
const uint8_t RST_OLED =  4; //OLED Reset

const uint8_t ADDRES_OLED =  0x3C;
const int sda = 5;
const int scl = 26;
const uint8_t Horizontal_pixel = 128;
const uint8_t Vertical_pixel = 64;

ESP32_SPIFFS_SSD1331_Gadgets ESSG;
ESP32_I2C_SSD1306 ssd1306(ADDRES_OLED, sda, scl, Horizontal_pixel, Vertical_pixel);
ESP32_SSD1331 _ssd1331(SCLK_OLED, MISO_OLED, MOSI_OLED, CS_OLED, DC_OLED, RST_OLED);
ESP32_SPIFFS_ShinonomeFNT _SFR;
ESP32_WebGet _EWG;

enum { MaxTxtByte = 500, Disp_Max_Num = 2, Disp_txt = 16};

uint8_t news_sj_txt[Disp_Max_Num][MaxTxtByte] = {}; //Shift_JIS コード文字列を格納
uint16_t news_sj_length[Disp_Max_Num]; //Shift_JIS コード文字列長

//-----ニュース記事文字列スクロール変数の初期化--------
uint16_t Scrolle_speed[Disp_Max_Num] = {10, 0}; //文字列スクロールインターバル時間
uint8_t font_buf[Disp_Max_Num][2][16] = {}; //スクロール時に投入するフォント１文字のバッファ
uint8_t disp_buf[Disp_Max_Num][Disp_txt][16] = {}; //実際にディスプレイに表示するフォントバッファ

uint16_t sj_cnt[Disp_Max_Num] = {}; //Shift_JISコード半角文字数カウント
uint8_t Zen_or_Han[Disp_Max_Num] = {}; //全角か半角かを判断する変数
uint32_t SclTime[Disp_Max_Num] = {};
boolean scl_reset[Disp_Max_Num] = {false, false};

uint8_t H_size[Disp_Max_Num] = {1, 2}; //OLED SSD1306文字横幅サイズアップ
uint8_t V_size[Disp_Max_Num] = {1, 4}; //OLED SSD1306文字縦幅サイズアップ

uint8_t X0 = 0, X1 = 95, Y0 = 0, Y1 = 63; //SSD1331 ディスプレイ表示座標位置
 //SSD1331 256color, Max red=7, green=7, blue=3
uint8_t red = 0, green = 7, blue = 0;

uint8_t disp_number;

//-----NTP時刻GET設定---------
uint32_t NTP_LastTime = 0;

//-----Yahoo記事取得引数初期化-------------------------
uint64_t NewsGetLastTime = 0;
uint64_t WeatherGetLastTime = 0;
bool News_first_get = true;
bool Weather_first_get = true;
bool News_get = false;
bool Weather_get = false;
String weather_str;

//*****************セットアップ******************************
void setup() {
  Serial.begin(115200);
  Serial.println();
  Serial.print(F("Connecting to "));
  Serial.println(ssid);

  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
      delay(500);
      Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  delay(1000);

  _ssd1331.SSD1331_Init(); //OLED SSD1331 初期化

  _SFR.SPIFFS_Shinonome_Init3F(UTF8SJIS_file, Shino_Half_Font_file, Shino_Zen_Font_file); //ライブラリ初期化。３ファイル同時に開く

  ESSG.Gadgets_MyFont_Init(MyFont_file); //自作フォント初期化
  delay(10);

  _EWG.EWG_NTP_TimeLib_init(9, "time.windows.com"); //NTPサーバー取得初期化
  _EWG.NTP_OtherServerSelect(9); //NTPサーバーと接続できなかった場合、他のNTPサーバーと接続できるか試す関数

  ssd1306.SSD1306_Init(400000); //I2C Max=400kHz
  ssd1306.Display_Clear_All();

  YahooNewsGET(0, 180000); //180秒毎に天気取得
  YahooWeatherGET(48, 180000); //180秒毎に天気取得

  SclTime[0] = millis(); SclTime[1] = millis();

  TaskHandle_t th; //マルチタスクハンドル定義
  xTaskCreatePinnedToCore(Task1, "Task1", 8192, NULL, 5, &th, 0); //マルチタスク実行
}
//************* メインループ ****************************************
void loop() {
  disp_number = 0;

  ESSG.Scroll_1_line(0, disp_number, red, green, blue, Scrolle_speed[disp_number], news_sj_txt[disp_number], news_sj_length[disp_number], &News_get);
  ESSG.ShinonomeClock_YMD(0, 16, 3, 3, 3); //東雲フォント年月日表示
  ESSG.MyFontClock_Weekday(80, 16, 7, 7, 3); //自作フォント曜日表示
  ESSG.Shinonome_Sec_Clock(80, 32, 'H', 'V', 0, 0, 15, 7, 0, 1); //東雲フォント秒表示
  ESSG.MyFont_HM_Clock(0, 32, 'H', 'V', 'H', 'V', 0, 0, 1, 1, 50, 7, 0, 1); //自作フォント時分表示

  if(Weather_get){ //サーバーから天気予報取得できたら、OLED表示を更新
    ESSG.YahooJ_Weather_TodayTomorrow(48, weather_str);
    Weather_get = false;
  }

  disp_number = 1;
  if(millis() - SclTime[disp_number] > Scrolle_speed[disp_number]){
    if(ssd1306.Scroller_Font8x16_PageReplace(&scl_reset[disp_number], Disp_txt/H_size[disp_number], 0, Zen_or_Han[disp_number], font_buf[disp_number], disp_buf[disp_number])){
      Zen_or_Han[disp_number] = _SFR.Sjis_inc_FntRead_Rot(&sj_cnt[disp_number], -90, 0, disp_number, news_sj_txt[disp_number], news_sj_length[disp_number], font_buf[disp_number]);
    }
    ssd1306.SizeUp_8x16_Font_DisplayOut(H_size[disp_number], V_size[disp_number], Disp_txt/H_size[disp_number], 0, 0, disp_buf[disp_number]);
    SclTime[disp_number] = millis();
  }
}
//************* マルチタスク ****************************************
void Task1(void *pvParameters){
  while(1){
    YahooNewsGET(0, 180000); //180秒毎に天気取得
    YahooWeatherGET(48, 180000); //180秒毎に天気取得
    _EWG.NTP_Get_Interval(180000); //180秒毎にNTPサーバーから時刻取得
    delay(1); //これは絶対必要
  }
}
//************** Yahoo RSS ニュースガジェット ************************
void YahooNewsGET(uint8_t y0, uint32_t get_interval){
  if((News_first_get == true) || ((millis() - NewsGetLastTime) > get_interval)){
    char web_get_time[6];
    sprintf(web_get_time, "%02d:%02d", hour(), minute()); //ゼロを空白で埋める場合は%2dとする
    String news_str = "◆ " + String(web_get_time) + " ";

    news_str += _EWG.EWG_https_Web_Get("news.yahoo.co.jp", "/rss/topics/sports.xml", '\n', "</rss>", "<title>", "</title>", "◆ ");

    Serial.print("News Get[0] = "); Serial.println( news_str );
    Serial.flush(); //シリアル出力が終わるまで待つ

    disp_number = 0;
    news_sj_length[disp_number] = _SFR.UTF8toSJIS_convert(news_str, news_sj_txt[disp_number]);
    news_str = "◆ " + String(web_get_time) + " ";
    news_str += _EWG.EWG_https_Web_Get("news.yahoo.co.jp", "/rss/topics/top-picks.xml", '\n', "</rss>", "<title>", "</title>", "◆ ");
    Serial.print("News Get[1] = "); Serial.println( news_str );
    Serial.flush(); //シリアル出力が終わるまで待つ

    disp_number = 1;
    news_sj_length[disp_number] = _SFR.UTF8toSJIS_convert(news_str, news_sj_txt[disp_number]);
    NewsGetLastTime = millis();
    News_first_get = false;
    News_get = true;

    disp_number = 0;
    sj_cnt[disp_number] = 0;
    Zen_or_Han[disp_number] = _SFR.Sjis_inc_FntRead(&sj_cnt[disp_number], disp_number, news_sj_txt[disp_number], news_sj_length[disp_number], font_buf[disp_number]);
    scl_reset[disp_number] = true;

    disp_number = 1;
    sj_cnt[disp_number] = 0;
    Zen_or_Han[disp_number] = _SFR.Sjis_inc_FntRead_Rot(&sj_cnt[disp_number], -90, 0, disp_number, news_sj_txt[disp_number], news_sj_length[disp_number], font_buf[disp_number]);
    scl_reset[disp_number] = true;
  }
}
//************** Yahoo RSS 天気予報ガジェット *************************
void YahooWeatherGET(uint8_t y0, uint32_t get_interval){
  if((Weather_first_get == true) || ((millis() - WeatherGetLastTime) > get_interval)){
    //東京の天気予報
    weather_str = _EWG.EWG_https_Web_Get("rss-weather.yahoo.co.jp", "/rss/days/4410.xml",  '>', "</rss", "】 ", " - ", "|");    
    Serial.print("Weather forecast = "); Serial.println(weather_str);
    Serial.flush(); //シリアル出力が終わるまで待つ
    WeatherGetLastTime = millis();
    Weather_get = true;
    Weather_first_get = false;
  }
}

コンパイル書き込み実行

最初に述べたように、2018/01/24時点の最新版 Arduino core for ESP32 で、フォントが上手く読み込めない場合は、サンプルスケッチの SPIFFS_Test をコンパイルしてから、先のスケッチをコンパイルしてみてください。

最初の動画のように表示されればＯＫです。
ただ、もう一つ、重要な注意点があります。
※裏側の基板の放熱が必要なので、長い間動作させる場合は、ケースを浮かせてください！

終わりに

どうでしょうか？
上手く動作しましたでしょうか。

今回は FRISK ケース加工が目的でしたので、ライブラリやプログラムの説明は大幅省略させていただきました。
実はそれの編集が一番大変なので、今後省略する方向にもっていきたいと思っています。

本当は 3D プリンターを使った方が綺麗に仕上がりますが、最近はまったく使っていないので、手軽に入手できる FRISK ケースにしてみました。
3D プリンターは一旦離れてしまうと、使い始めるのに億劫になってしまいますね。

今回の FRISK ケース加工では、いろいろなデバイスに置き換えることが簡単にできて便利です。
ただ、先にも述べたように接触不良しやすいので注意が必要です。
ケースから取り出して使いまわしたりしないのであれば、ハンダ付けして固定した方が良いですね。

ということで、今回はここまでです。

ではまた・・・。