Arduino – ESP32 の関数の参照渡し、ポインタ渡し、String渡しについて考えてみた

関数の引数にクラスや構造体を使う場合、メモリ節約のために参照渡しかポインタ渡しを使うべし

では、関数の引数にクラスを使った場合、メモリの使われ方に注目してみたいと思います。
まずは、String型の文字列をシリアルモニタに表示させる簡単なプログラムです。
以下をご覧ください。

【ソースコード】 (※無保証　※PCの場合、ダブルクリックすればコード全体を選択できます)

class Test {
  public:
    String str1;
    String str2;
};

void setup() {
  Serial.begin(115200);
  Serial.println();

  Test test;

  test.str1 = "abcdefghijklmnopqrstuvwxyz";
  test.str2 = "ABCDEFGHIJKLMNOPQRSTUVWXYZ";

  printTestData( test );
}

void loop() {
  Test test;
  test.str1 = "abcdefghijklmnopqrstuvwxyz";
  test.str2 = "ABCDEFGHIJKLMNOPQRSTUVWXYZ";
  printTestData( test );
  delay(30000);
}

void printTestData( Test t ) {
  Serial.println( t.str1 );
  Serial.println( t.str2 );
}

実行結果

これは関数の引数にクラスを使って値を渡しています。
String型もクラスの一つですが、ヒープメモリを使うため、空きサイズを測るために便利なので使いました。
（String クラスについては、後で詳しく述べます。）

これ、特に何も問題無いように見えますね。
では、ヒープメモリの使われ方を見てみたいと思います。
要所要所に Arduino – ESP32 のヒープメモリ空きサイズを見るため、以下の関数、

esp_get_free_heap_size()

を置いて、シリアルモニタに表示させるプログラムに替えてみます。
以下の様な感じです。

【ソースコード】 (※無保証　※PCの場合、ダブルクリックすればコード全体を選択できます)

class Test {
  public:
    String str1;
    String str2;
};

void setup() {
  Serial.begin(115200);
  Serial.println();

  Serial.print( "Free Heap Size(setup0) = " );
  Serial.println( esp_get_free_heap_size() );

  Test test;

  Serial.print( "Free Heap Size(setup1) = " );
  Serial.println( esp_get_free_heap_size() );

  test.str1 = "abcdefghijklmnopqrstuvwxyz";
  test.str2 = "ABCDEFGHIJKLMNOPQRSTUVWXYZ";

  Serial.print( "Free Heap Size(setup2) = " );
  Serial.println( esp_get_free_heap_size() );

  printTestData( test );

  Serial.print( "Free Heap Size(setup3) = " );
  Serial.println( esp_get_free_heap_size() );
}

void loop() {
  Serial.println("-------------------------------");
  Serial.print( "Free Heap Size(main loop0) = " );
  Serial.println( esp_get_free_heap_size() );

  Test test;

  Serial.print( "Free Heap Size(main loop1) = " );
  Serial.println( esp_get_free_heap_size() );

  test.str1 = "abcdefghijklmnopqrstuvwxyz";
  test.str2 = "ABCDEFGHIJKLMNOPQRSTUVWXYZ";

  Serial.print( "Free Heap Size(main loop2) = " );
  Serial.println( esp_get_free_heap_size() );

  printTestData( test );

  Serial.print( "Free Heap Size(main loop3) = " );
  Serial.println( esp_get_free_heap_size() );
  delay(30000);
}

void printTestData( Test t ) {
  Serial.print( "Free Heap Size(function0) = " );
  Serial.println( esp_get_free_heap_size() );
  Serial.println( t.str1 );
  Serial.println( t.str2 );
}

実行結果

これを見ると、ソースコードの 14行目の
Test test
を見てください。
Test クラスに、新たに test オブジェクトという実体が生成されて、メモリが 64 byte 食われます。
これはクラスや構造体を使う場合は必ずメモリが食われるので仕方ありません。
ここからヒープメモリの空きサイズが減っています。

そして、19-20行で test オブジェクトの String 型変数に文字列を代入することによって、更にメモリが 36 byte 減っています。
文字列は 26×2 = 52 文字なので、52 byte 前後かと思われますが、かなり異なりますね。
これの原因はいろいろある為、ここでは割愛します。

25行目で自作関数の printTestData に入ったところで、更に大幅に 104 byteメモリが減っています。
ここが納得いかないところだと思います。

その関数を抜けると、関数に入る前のメモリに復活して、さらにセットアップ関数を抜けてメインループに入るときに、全てのメモリが解放されて、最初のヒープメモリサイズに復活していることが分かると思います。

このような関数の引数の渡し方は、「値渡し」というものです。

では次に、最初の方で述べたように、printTestData関数の引数に ‘&’ を付けてみます。
以下のようなスケッチになります。

【ソースコード】 (※無保証　※PCの場合、ダブルクリックすればコード全体を選択できます)

class Test {
  public:
    String str1;
    String str2;
};

void setup() {
  Serial.begin(115200);
  Serial.println();

  Serial.print( "Free Heap Size(setup0) = " );
  Serial.println( esp_get_free_heap_size() );

  Test test;

  Serial.print( "Free Heap Size(setup1) = " );
  Serial.println( esp_get_free_heap_size() );

  test.str1 = "abcdefghijklmnopqrstuvwxyz";
  test.str2 = "ABCDEFGHIJKLMNOPQRSTUVWXYZ";

  Serial.print( "Free Heap Size(setup2) = " );
  Serial.println( esp_get_free_heap_size() );

  printTestData( test );

  Serial.print( "Free Heap Size(setup3) = " );
  Serial.println( esp_get_free_heap_size() );
}

void loop() {
  Serial.println("-------------------------------");
  Serial.print( "Free Heap Size(main loop0) = " );
  Serial.println( esp_get_free_heap_size() );

  Test test;

  Serial.print( "Free Heap Size(main loop1) = " );
  Serial.println( esp_get_free_heap_size() );

  test.str1 = "abcdefghijklmnopqrstuvwxyz";
  test.str2 = "ABCDEFGHIJKLMNOPQRSTUVWXYZ";

  Serial.print( "Free Heap Size(main loop2) = " );
  Serial.println( esp_get_free_heap_size() );

  printTestData( test );

  Serial.print( "Free Heap Size(main loop3) = " );
  Serial.println( esp_get_free_heap_size() );
  delay(30000);
}

void printTestData( Test &t ) {
  Serial.print( "Free Heap Size(function0) = " );
  Serial.println( esp_get_free_heap_size() );
  Serial.println( t.str1 );
  Serial.println( t.str2 );
}

実行結果

どうでしょうか？
これは、「参照渡し」という方法です。
クラスのオブジェクトの中の値を格納しているメモリのアドレスだけを関数に渡して、メモリを消費している実体は渡さないというやつです。

これを見ると、printTestData関数に入る前と、入った後、関数を抜けた後で、ヒープメモリサイズは変わりありませんね。
これは、文字列がメモリされているアドレスだけを関数に渡しているので、メモリは消費されません。

ですが、これの前のプログラムのように、’&’ を付けない「値渡し」の場合、新たなクラスオブジェクトが生成されて、それに文字列を代入していくので、格納されているメモリをコピー（複製）した状態になり、メモリが余分に消費されてしまいます。
要するにネットに情報があるように、コピーコンストラクタが作成されてしまうというやつです。
クラスのパラメーターが多い場合などは、意図しない無駄なメモリ消費をしてしまうので、もったいないですね。

これは、ポインタ熟練者なら当然のことかもしれませんが、プログラミングビギナーには解らないことだと思います。
私もつい最近まで知りませんでした。
今までなんと無駄にメモリを消費していたことか・・・。

とにかく、自作関数で構造体やクラスを引数とする場合は、’&’ を付けるだけでメモリ節約になると思っておけば良いと思います。

ただ、この参照渡しを使う場合、注意点があります。
最初の方で述べた const を付けたのはいったいどういう意味だったのでしょうか？
次で述べたいと思います。